<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" 
	layout="absolute" applicationComplete="init()" width="1024" height="660" 
	borderColor="#FFFFFF" backgroundColor="#FFFFFF" backgroundGradientAlphas="[1.0, 1.0]" 
	backgroundGradientColors="[#FFFFFF, #FFFFFF]" xmlns:reflexutil="net.kandov.reflexutil.*">
	<mx:Metadata>
	[Event(name="VIS_LOADED")]
	</mx:Metadata>

	<mx:Script>
		<![CDATA[
			import lastfmvis.CheaterEvent;
			import lastfmvis.LastfmVisHolder;
			import flare.util.Strings;
		
			import Last_fm_vis;
			import mx.events.SliderEvent;
			import mx.controls.sliderClasses.Slider;
			import mx.core.Application;
			
			private var holder:LastfmVisHolder;
			
			private var sliderInitted:Boolean = false;
		
			private function init():void{
				holder = new LastfmVisHolder(100, 0);
				Application.application.addEventListener(Last_fm_vis.VIS_LOADED, initUI);
				Application.application.addEventListener(Last_fm_vis.DRILL_DOWN, addDrillDownFilter);
				addChildAt(holder, numChildren - 1);
				stage.focus = holder.usernameEntries[0];
			}
			
			private function addDrillDownFilter(e:CheaterEvent):void {
				holder.filterChanged(e.params["type"], e.params["name"], e.params["source"]);
			}
			
			private function initUI(e:CheaterEvent):void {
				holder.visLoaded(e.params["source"]);
				if (sliderInitted)
					return;
				compareButton.enabled = true;
				var numDates:uint = holder.dates.length;
				var numLabels:int = 5;
				var step:Number = (holder.dates.length-1)/(numLabels-1);
				var labels:Array = [];
				
				dateSlider.minimum = 0;
				dateSlider.maximum = holder.dates.length-1;
				dateSlider.values[0] = dateSlider.minimum;
				dateSlider.values[1] = dateSlider.maximum;
				//dateSlider.snapInterval = (dateSlider.maximum - dateSlider.minimum) / vis.dates.length;
				dateSlider.snapInterval = 1;
				
				dateSlider.x = holder.x-30;
				dateSlider.y = holder.y + holder.height;
				dateSlider.width = holder.width - 40;
				dateSlider.visible = true;
				
				for(var i:uint=0; i<numLabels; i++) {
					var pos:Number = i * step;
					var date:Date;
					// If date rounds up...
					if (Math.round(pos) != Math.floor(pos)) {
						// Make date midpoint between two actual datapoints
						var firstDate:Date = holder.dates[Math.floor(pos)];
						date = new Date(firstDate.time + (holder.dates[Math.round(pos)].time - firstDate.time)/2);
					} else {
						date = holder.dates[Math.round(pos)];
					}
					labels.push(Strings.format("{0:MM/dd/yy}", date));
				}
				//dateSlider.labels = [Strings.format("{0:MM/dd/yy}", vis.dates[0]),
				//					 Strings.format("{0:MM/dd/yy}", vis.dates[dateSlider.maximum])];
				dateSlider.labels = labels;
				holder.drawMiniGraph(0, 550, dateSlider.width - 59, 30);
				sliderInitted = true;
			}
			
			private function compareUsers(e:Event):void {
				holder.addVisualization();
				compareButton.enabled = false;
			}
			
            private function sliderChangeTwo(event:SliderEvent):void {
                var ct:Slider=Slider(event.currentTarget);
               	
               	holder.changeMinDate(ct.values[0]);
               	holder.changeMaxDate(ct.values[1]);
            }

            private function sliderDataTipFunc(val:String):String {
                return Strings.format("Date: {0:MM/dd/yy}", holder.dates[val.valueOf()]);
            }
		]]>
	</mx:Script>

<!--	<mx:HSlider x="102" y="594" minimum="0" maximum="100" thumbCount="2" liveDragging="true" change="sliderChangeTwo(event);"/> -->
	<mx:Button id="compareButton" label="Compare Two Users" x="830" y = "400" click="compareUsers(event);" enabled="false" />
	<mx:HSlider id="dateSlider" x="102" y="594" visible="false" thumbCount="2" liveDragging="false" labelOffset="30" dataTipPlacement="bottom"
				change="sliderChangeTwo(event);" 
				dataTipFormatFunction="sliderDataTipFunc"/>
	<!-- reflexutil:ReflexUtil / -->
</mx:Application>